Russian Users MikroTik | Форум пользователей MikroTik

Код: Выделить всё

:local scriptName "Script_ChangeTTL"
:local lteInterface "lte1"
:local mangleComment "lte1_ChangeTTL"
:local dnsServer "1.1.1.1"
:local domain "ya.ru"
:local pingSeconds 10

:put "Script Start"
:local startScriptsCount [:len [/system script job find script=$scriptName]]

if ($startScriptsCount=1) do={
   do { 
       if ([/interface get $lteInterface running] = true) do={
          :put "   $lteInterface running"

          do {
             :resolve $domain server=$dnsServer
             :put "   DNS is working"    
          } on-error={    
            :local strTTL "set:65" 
            :local mangleID [/ip firewall mangle find comment="$mangleComment"]
            if ([:len $mangleID] = 0) do={        
               :put "   Add new mangle rule"
               /ip firewall mangle add action=change-ttl chain=postrouting new-ttl=$strTTL passthrough=yes comment=$mangleComment out-interface="$lteInterface" disabled=no
               :set mangleID [/ip firewall mangle find comment="$mangleComment"]
            } else={
              :put "   Renew mangle rule"
              /ip firewall mangle set [$mangleID] action=change-ttl chain=postrouting new-ttl=$strTTL passthrough=yes out-interface="$lteInterface" disabled=no
            }

            :local statusPing ([/ping address=$dnsServer count=1  as-value]->"status") 
            if ($statusPing = "timeout") do={
               :set strTTL "set:64"     
               :put "   ping $dnsServer timeout. new-ttl=$strTTL" 
               /ip firewall mangle set [$mangleID] new-ttl=$strTTL
            } else={          
              if ($statusPing = "no route to host") do={ 
                 :put "   Please reconnect the $lteInterface modem. statusPing = $statusPing"
              }
            } 

            :local iTime 0
            while (($statusPing = "timeout") and ($iTime<$pingSeconds)) do={  
                  :delay 700ms
                  :set statusPing ([/ping address=$dnsServer count=1  as-value]->"status")
                  :set iTime ($iTime + 1)
                  :put "   How many times did you ping: $iTime"    
            }

            if ($strTTL != "set:65") do={
               :set strTTL "set:65"
               :put "   new-ttl=$strTTL"
               /ip firewall mangle set [$mangleID] new-ttl=$strTTL
            }

            do {
                :resolve $domain server=$dnsServer
                :put "   Result_Good"
            } on-error={
              :put "   Result_Bad"
            }
          }
       } else={
         :put "   $lteInterface NOT running"
       }
  } on-error= {
    :put "   $lteInterface not connected"
  }
} else={
  :put "   The script is already running"
}
:put "Script End"