Russian Users MikroTik | Форум пользователей MikroTik

Код: Выделить всё

# Telegram notification script by Virtue
# https://forummikrotik.ru/viewtopic.php?f=14&t=12043
# tested on ROS 6.48
# updated 2021/02/18

:do {
    :local botID "bot1111111111:XXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXXX";
    :local chatID "-111111111";
    :local nameID  [/system identity get name];
    :delay 10;
    :local timeNow [/system clock    get time];
    :local logs;
    :if ([:pick $timeNow 0 2] < 03) do={
        :local date [/system clock get date];
        :foreach h in=[/log find] do={
            :local htime [/log get $h time];
            :if (($htime ~ [:pick $date 0 6]) and ([:pick $htime 7 15] > ($timeNow - 00:01:00))) do={ :set logs ($logs, $h); }
        }
    } else={ :set logs [/log find time >= ($timeNow - 00:01:00)]; }
    :if ([:len $logs] > 0 ) do={
        :local messages;
        :local presence false;
        :foreach i in=$logs do={
            :local imessage [/log get $i message];
            :local topics   [/log get $i topics];
            :if ($imessage ~"telnet" and $imessage ~"logged in") do={} else={
                :if ($topics ~"caps" || $topics ~"wireless") do={
                    :if ($imessage ~ "[0-F][0-F]:[0-F][0-F]:[0-F][0-F]:[0-F][0-F]:[0-F][0-F]:[0-F][0-F]") do={
                        :foreach k  in=[/ip dhcp-server lease find dynamic=no disabled=no] do={
                            :local mac [/ip dhcp-server lease get $k mac-address];
                            :if ($imessage ~ "$mac") do={ :set presence true; }
                        }
                    }
                    :if (presence = false) do={
                        :local currentTime [ /log get $i time ];
                        :set messages ($messages.$currentTime." ".$imessage."%0A%0A");
                    }
                }
                :if ($topics ~"warning" || $topics ~"error" || $topics ~"critical" || $imessage ~"logged in") do={
                    :if ($imessage ~ "[0-F][0-F]:[0-F][0-F]:[0-F][0-F]:[0-F][0-F]:[0-F][0-F]:[0-F][0-F]") do={
                        :foreach k  in=[/ip dhcp-server lease find dynamic=no disabled=no] do={
                            :local mac [/ip dhcp-server lease get $k mac-address];
                            :if ($imessage ~ "$mac") do={ :set imessage ($imessage." / ".[/ip dhcp-server lease get $k comment]); }
                        }
                    }
                    :local currentTime [ /log get $i time ];
                    :set messages ($messages.$currentTime." ".$imessage."%0A%0A");
                }
            }
        }
        :if ([:len $messages] > 0 ) do={
            put ($messages);
            /tool fetch keep-result=no url="https://api.telegram.org/$botID/sendmessage?chat_id=$chatID&text= $nameID : %0A$messages";
        }
    }
}